Автоматическая генерация подписи на основе данных из AD в Outlook

Небольшой скриптик, который берет из AD ФИО, должность, номер телефона и email адрес сотрудника. Мы задаем шрфит, размер и создаем с этими параметрами подпись. В конце скрипт активирует подпись в Outlook для всех ответов и форвардов. Подпись на новые письма он не затрагивает.

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strPhone = objUser.telephoneNumber
strEmail = objuser.mail

Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature
Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.ParagraphFormat.Space1

objSelection.TypeText CHR(11)
objSelection.TypeText CHR(11)
objSelection.Font.Name = "Trebuchet MS"
objSelection.Font.Bold = True
objSelection.Font.Size = "10"
objselection.Font.Color = RGB(115, 120, 122)
objSelection.TypeText strName & " | " & strTitle
objSelection.TypeText CHR(11)
objSelection.TypeText CHR(11)

objSelection.Font.Size = "8"
objselection.Font.Color = RGB(0, 32, 90)
objSelection.TypeText "office tel: "
objselection.Font.Color = RGB(115, 120, 122)
objSelection.TypeText strPhone
objSelection.TypeText CHR(11)

objselection.Font.Color = RGB(0, 32, 90)
objSelection.TypeText "email: "
objselection.Font.Color = RGB(115, 120, 122)
objSelection.TypeText strEmail
objSelection.TypeText CHR(11)

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = False
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objDoc.Close
objWord.Quit

WScript.Quit 0